以下是唐能通短线是银公式集 值得推荐！
唐能通短线是银公式集 值得推荐！
部分《短线是银》公式集
条件选股公式：D!CSFR (出水芙蓉) 缺省周期：日线
==============================================================
MA1:=MA(CLOSE,20);
MA2:=MA(CLOSE,40);
MA3:=MA(CLOSE,60);
{A1:=(OPEN<MA1 AND OPEN<MA2) OR (OPEN<MA2 AND OPEN<MA3) OR (OPEN<MA1 AND OPEN<MA3);}
A1:=OPEN<MA1 OR OPEN<MA2 OR OPEN<MA3;
A2:=C>MAX(MA1,MAX(MA2,MA3));
A3:=V/MA(V,30)>1.2;
A4:=C/REF(C,1)>1.049;
TJ:=A1 AND A2 AND A3 AND A4;
TJ;
==============================================================
出水芙蓉：
股价长期在季均线之下滑跌，某日突然放量冲过季均线并收在季均线之上，这一根阳线称为出水芙蓉。
操作：
在出现出水芙蓉图形当日买入或之后逢低买入。
==============================================================
条件选股公式：D!DFDDP (多方叠叠炮) 缺省周期：日线
==============================================================
A1:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN;
TJ:=A1 AND REF(BARSLAST(A1),1)<9 AND C/REF(C,10)>1.1;
==============================================================
多方叠叠炮（两阳夹一阴）：
阳-阴-阳的K线组合，在一定周期内出现两次，且后者是在上升一定空间后出现。
==============================================================
条件选股公式：D!DFH (东方红大阳升) 缺省周期：日线
==============================================================
HSL:=V/CAPITAL*100;
YB:=HSL>4 AND C>REF(C,1);
A1:=COUNT(YB,13)>=3;
A2:=C/REF(C,1)>1.049 AND HSL>5;
A3:=REF(SUMBARS(V,CAPITAL),13)>89;
A4:=HIGH/C<1.021;
A5:=COUNT(C/REF(C,1)>1.04,10)<5;
A6:=IF(COUNT(HSL>4,5)>=3,0,1);
ZTJ:=A1 AND A2 AND A3 AND A4 {AND A5 AND A6};
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);
==============================================================
东方红大阳升：
当股价底部形成时，日K线图上会出现多根放量阳线，然后大阳突破，这就是东方红大阳升。
97、98、99三年胜率64.67%（302：165）
操作：
在出现东方红大阳升后逢低买入。
==============================================================
条件选股公式：D!DFP (多方炮) 缺省周期：日线
==============================================================
A1:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN;
==============================================================
多方炮（两阳夹一阴）：
阳-阴-阳的K线组合。
==============================================================
条件选股公式：D!DGLYT (倒挂老鸭头) 缺省周期：日线
==============================================================
MA5 := MA(close,5);
MA10 := MA(close,10);
MA60 := MA(close,60);
pday1 := barslast(cross(ma60,ma5));{5日均线下穿60日均线}
pday2 := barslast(cross(ma60,ma10));{10日均线下穿60日均线，至此形成鸭颈部}
pday3 := barslast(low=llv(low,pday2));{形成头部，要反弹}
pday4 := barslast(cross(ma5,ma10));{反弹后，5日均线和10日均线金叉}
pday5 := barslast(cross(ma10,ma5));{反弹不久，5日均线和10日均线形成死叉，形成嘴部}
a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;
a2:= count(cross(ma10,ma5),pday2)=1;
A1 AND A2;
==============================================================
倒挂老鸭头：
（1）采用5、10和60周期的价格平均线。当5日、10日均线跌破60日平均线后，形成鸭颈部。
（2）股价反弹时形成的低点形成鸭头部。
（3）当股价反弹不久，5日、10日均线再次死叉向下形成鸭嘴部。
操作：
（1）在5日、10日均线放量跌破60日平均线形成鸭颈部时卖出。
（2）在鸭嘴部附近5日、10日均线死亡交叉时卖出。
（3）当股价放量跌破鸭头顶瞬间时卖出。
==============================================================
条件选股公式：D!DIFSCLX (DIF上穿零线) 缺省周期：日线
==============================================================
dif:=ema(close,12)-ema(close,26);
count(dif>=0,60)=1 and dif>=0;
==============================================================
DIF上穿零线：
（1）当股价长期下跌后，DIF始终运行在零线以下，呈现负数。
（2）当股价底部抬高后或股价冲过季均线后，会出现DIF上穿零线，呈现正数。
（3）有时股价并未启动，但DIF会率先上穿零线，对未来的涨势有预报作用。
操作：
（1）在DIF上穿零线时买入股票。
（2）在DIF上穿零线后等待三金叉见底时逢低买入。
==============================================================
条件选股公式：D!DIFXCLX (DIF下穿零线) 缺省周期：日线
==============================================================
dif:=ema(close,12)-ema(close,26);
count(dif<=0,60)=1 and dif<=0;
==============================================================
DIF上穿零线：
（1）当股价长期上涨后，DIF始终运行在零线以上，呈现正数。
（2）当股价难创新高或股价跌破季均线时，会出现DIF下穿零线，呈现负数。
（3）有时股价跌势还未展开，但DIF会率先下穿零线，对未来的跌势有预报作用。
操作：
（1）在DIF下穿零线时卖出股票。
（2）在DIF下穿零线后等待三死叉见顶时逢高卖出。
==============================================================
条件选股公式：D!DTZD (断头铡刀) 缺省周期：日线
==============================================================
MA1:=MA(CLOSE,20);
MA2:=MA(CLOSE,40);
MA3:=MA(CLOSE,60);
A1:=OPEN>MA1 OR OPEN>MA2 OR OPEN>MA3;
A2:=C<MIN(MA1,MIN(MA2,MA3));
A3:=COUNT(C>MIN(MA1,MIN(MA2,MA3)),34)>30;
A4:=C/REF(C,1)<0.97;
TJ:=A1 AND A2 AND A3 AND A4;
==============================================================
断头铡刀：
股价长期在季均线之上爬升，某日突然放量跌破季均线并收在季均线之下，这一根阴线称为断头铡刀。
操作：
在出现断头铡刀图形当日卖出或之后逢高派发。
注意：本公式用于空头选股。
==============================================================
条件选股公式：D!FLGT (放量过头) 缺省周期：日线
==============================================================
highprice := hhv(high,60); {60日内最高价}
A1:= Close>highprice;{股价在冲击前高位}
A2:= (vol>ma(vol,5)*2.5) or (COUNT(Vol>ma(vol,10),6)>4);{近期明显放量}
A1 AND A2;
==============================================================
放量过头：
（1）股价在冲过前一个头部时放出巨大的成交量。
（2）有时是单根的巨大阳线，有时是温和放量的几根阳线，总之在冲过前头部时有成交量的配合。
操作：
（1）当出现巨量冲过前头部时，一般都应及时跟进。
（2）当出现几天的温和放量时，也应积极介入。
（3）前头部不会永远阻碍股价上升，而股价通过前头部时只要能放量一般都可买入。
（4）前头部是上升浪的底部。
==============================================================
条件选股公式：D!HMCSF (黑马草上飞) 缺省周期：日线
==============================================================
LCZ:=(C-MA(C,60))/MA(C,60)*100;
A1:=COUNT(MA(C,60)>REF(MA(C,60),1),100)>95;
A2:=COUNT(LCZ<20,100)>95;
A3:=COUNT(C>MA(C,60),100)>80;
A4:=C/REF(C,1)>1.04;
A5:=V/CAPITAL*100>2.8;
ZTJ:=A1 AND A2 AND A3 AND A4 AND A5;
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);
==============================================================
黑马草上飞：
1、60日价格均线平稳上扬。
2、日K线按照60日均线斜率震荡上行。
3、经过大半年的震荡向上，终于向上突破。
操作：
发出信号后逢低积极介入。
==============================================================
条件选股公式：D!JYA (价压) 缺省周期：日线
==============================================================
参数描述： N1(1,300,20)N2(1,300,40)N3(1,300,60)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
YA:=COUNT(CROSS(MA2,MA1),21)=1 AND CROSS(MA3,MA2) AND
COUNT(CROSS(MA3,MA1),21)=1 AND
BARSLAST(CROSS(MA2,MA1))>BARSLAST(CROSS(MA3,MA1)) AND
BARSLAST(CROSS(MA3,MA1))>BARSLAST(CROSS(MA3,MA2)) AND
MA1<REF(MA1,1);
==============================================================
价压：
短期、中期、长期三条均线自上而下扭转向下所形成的封闭三角形。常用的有季压与月压：
由5、10、20日均线这个月均线系统组成的压为“月压”；
由20、40、60日均线这个季均线系统组成的压为“季压”；
操作：
1、在三个死亡交叉点附近逢高卖出。
2、看清楚价压后在反弹时逢高卖出。
注意：本公式为空头公式。
==============================================================
构成价压的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月压取5，10，20；
季压取20，40，60；
==============================================================
条件选股公式：D!JZZ (金蜘蛛) 缺省周期：日线
==============================================================
参数描述： N1(1,300,5)N2(1,300,10)N3(1,300,20)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
A1:=COUNT(CROSS(MA2,MA3),2)=1;
A2:=COUNT(CROSS(MA1,MA3),2)=1;
A1 AND A2;
==============================================================
金蜘蛛：
短期、中期、长期三条均线自上而下，并且扭转向上所形成的结点。
操作：
1、在金蜘蛛出现后应逢低买入。
2、在金蜘蛛图形下出现量托，更应积极买入。
==============================================================
构成金蜘蛛的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：金蜘蛛取5，10，20日。
==============================================================
条件选股公式：D!KFP (空方炮) 缺省周期：日线
==============================================================
REF(CLOSE,2)<REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE<OPEN;
==============================================================
空方炮（两阴夹一阳）：
阴-阳-阴的K线组合。
==============================================================
条件选股公式：D!LBCJ (猎豹出击) 缺省周期：日线
==============================================================
M1:=MA(C,60);
A1:=COUNT(C<M1,33)>31;
A2:=CROSS(C,M1);
A3:=C/REF(C,1)>1.045;
A1 AND A2 AND A3;
==============================================================
猎豹出击：
股价长期在60日均线之下滑跌，某日突然拉大阳冲过60日线并收在60日均线之上，在日线中这一根阳线称为猎豹出击。
操作：
在出现猎豹出击图形当日买入或之后逢低买入。
==============================================================
条件选股公式：D!LDTLD (量顶天立地) 缺省周期：日线
==============================================================
A1:=V=HHV(V,120);
A2:=C/OPEN>1.049;
TJ:=A1 AND A2;
TJ AND (REF(BARSLAST(TJ),1)>80 OR BARSSINCE(TJ)=0);
==============================================================
量顶天立地：
某日出现半年来的天量，且收出大阳线。
本公式集有一个量顶天立地五彩K线公式D!LDTLDWC与本公式对应。
==============================================================
条件选股公式：D!LYT (老鸭头) 缺省周期：日线
==============================================================
MA5 := MA(close,5);
MA10 := MA(close,10);
MA60 := MA(close,60);
pday1 := barslast(cross(ma5,ma60));{5日均线上穿60日均线}
pday2 := barslast(cross(ma10,ma60));{10日均线上穿60日均线，至此形成鸭颈部}
pday3 := barslast(high=hhv(high,pday2));{形成头部，要下跌}
pday4 := barslast(cross(ma10,ma5));{下跌后，5日均线和10日均线死叉}
pday5 := barslast(cross(ma5,ma10));{回落不久，5日均线和10日均线形成金叉，形成嘴部}
a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;
a2:= count(cross(ma10,ma5),pday2)=1;
A1 AND A2;
==============================================================
老鸭头：
（1）采用5、10和60周期的价格平均线。当5日、10日均线放量上穿60日平均线后，形成鸭颈部。
（2）股价回落时形成的高点形成鸭头部。
（3）当股价回落不久，5日、10日均线再次金叉向上形成鸭嘴部。
操作：
（1）在5日、10日均线放量上穿60日平均线形成鸭颈部时买入。
（2）在鸭嘴部附近成交量芝麻点一带逢低买入。
（3）当股价放量冲过鸭头顶瞬间时介入。
==============================================================
条件选股公式：D!LZMD (量芝麻点) 缺省周期：日线
==============================================================
V1:=MA(V,40);
HSL:=V/CAPITAL*100;
A1:=COUNT(V/V1<1.3,14)>11;
A2:=CROSS(HSL,2);
A3:=C/REF(C,1)>1.025 AND C>OPEN;
ZTJ:=A1 AND A2 AND A3;
==============================================================
量芝麻点：
成交量连续出现萎缩，在量柱体图上表现为小芝麻点，连续的小芝麻点与40日量平均线形成一个小水坑。
操作建议：
最好K线浅幅回档，且成交量越小越好，当放量上行时买入。
==============================================================
条件选股公式：D!QLQS (青龙取水) 缺省周期：日线
==============================================================
A1:=MIN(MA(C,5),MA(C,10))>MA(C,60) AND CROSS(MA(C,5),MA(C,10));
A2:=MIN(MA(C,5),MA(C,10))/MA(C,60)<1.05;
A3:=COUNT(V<MA(V,10),10)>6;
A1 AND A2 AND A3;
==============================================================
青龙取水：
1、在5日、10日、60日均线图上，5、10日均线起伏不定，日K线在60日均线上逶迤。
2、龙头回到60日均线附近，犹如青龙取水，同时成交量萎缩
3、然后大涨。
操作：待龙头形成，成交量萎缩又放大后，逢低介入。
==============================================================
条件选股公式：D!QSGT (轻松过头) 缺省周期：日线
==============================================================
nday := hhvbars(high,120); {120日内最高价的周期数}
nday1:= nday-10; {最高点之后10日}
nday2:= nday+10; {庄家应该在nday1--nday2之间吸纳大部分筹码}
a1 := nday>=30;{确保高点出现的周期数大于30}
a2 := ref(sum(vol,20),nday1) > finance(7) * 0.4; {吸纳40%}
VMA:=MA(Vol,40);{40日量均线}
A3:=COUNT(Vol<VMA,nday1)/nday1>0.9;{成交量呈现芝麻点}
A4:=Close>=hhv(high,120);{股价在冲击前高位}
A5:=COUNT(Vol<(MA(vol,10)*1.3),10)>8;{近期无明显放量}
A1 AND A2 AND A3 AND A4 AND A5;
==============================================================
轻松过头：
（1）前一个头部下方的成交量巨大，股价筑头后开始回档。
（2）回档完毕后成交量呈量芝麻点，股价再次上扬冲击前一头部。
（3）轻松冲过前一头部并未明显放量。
操作：
（1）在前一头部成交量巨大时跟进。
（2）在回档完毕后成交量呈现芝麻点时逢低吸纳。
（3）最经济、最大利润化的方法是在轻松过头前的一瞬间迅速介入。
（4）前头部价格一般是上升浪的腰部。
==============================================================
条件选股公式：D!SJCJD (三金叉见底) 缺省周期：日线
==============================================================
nday := 5;
down := close/llv(low,60)<=1.2;
pma1 := ma(close,5);
pma2 := ma(close,10);
vma1 := ma(vol,5);
vma2 := ma(vol,10);
diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);
ppday := barslast(cross(pma1,pma2));
vvday := barslast(cross(vma1,vma2));
macdday := barslast(cross(diff,dea));
sjcjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);
==============================================================
三金叉见底：
（1）当股价长期下跌后开始企稳筑底，而后股价缓慢上升。有时会同时出现5日和10日均价线、5日和10日均量线、MACD的黄金交叉点，这是股价见底回升的信号。
（2）有时会伴随出现两阳夹一阴多方炮、出水芙蓉、量顶天立地和MACD上穿零线等图形。
操作：
（1）当出现三金叉后开始买入股票。
（2）或等股价回档时在10日均线附近逢低吸纳。
==============================================================
条件选股公式：D!SSCJD (三死叉见顶) 缺省周期：日线
==============================================================
nday := 5;
down := hhv(high,20)/high<=1.15;
pma1 := ma(close,5);
pma2 := ma(close,10);
vma1 := ma(vol,5);
vma2 := ma(vol,10);
diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);
ppday := barslast(cross(pma2,pma1));
vvday := barslast(cross(vma2,vma1));
macdday := barslast(cross(dea,diff));
sscjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);
==============================================================
三死叉见顶：
（1）当股价长期上涨后开始进入头部，而后股价缓慢下跌。有时会同时出现5日和10日均价线、5日和10日均量线、MACD的死亡交叉点，这是股价见顶回落的信号。
（2）有时会伴随出现两阴夹一阳空方炮、断头铡刀MACD下穿零线等图形。
操作：
（1）当出现三死叉后坚决卖出股票。
（2）或等股价反弹到10日均线附近逢高派发。
==============================================================
条件选股公式：D!SZZ (死蜘蛛) 缺省周期：日线
==============================================================
参数描述： N1(1,300,5)N2(1,300,10)N3(1,300,20)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
A1:=COUNT(CROSS(MA3,MA2),2)=1;
A2:=COUNT(CROSS(MA3,MA1),2)=1;
A1 AND A2;
==============================================================
死蜘蛛：
短期、中期、长期三条均线自下而上，并且扭转向下所形成的结点。
操作：
1、在死蜘蛛出现后应逢高派发。
2、在死蜘蛛图形下出现量压，更应加快派发。
注意：本公式为空头选股。
==============================================================
构成死蜘蛛的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：死蜘蛛取5，10，20日。
==============================================================
条件选股公式：D!TSJDXJ (天上井地下井) 缺省周期：日线
==============================================================
M1:=MA(C,5);
M2:=MA(C,10);
M3:=MA(C,20);
M4:=MA(C,30);
TSJ:=COUNT(CROSS(M3,M1),21)=1 AND COUNT(CROSS(M4,M1),21)>0 AND
COUNT(CROSS(M3,M2),21)>0 AND COUNT(CROSS(M4,M2),21)>0;
MM1:=MA(V,5);
MM2:=MA(V,10);
MM3:=MA(V,20);
MM4:=MA(V,30);
DXJ:=COUNT(CROSS(MM3,MM1),21)=1 AND COUNT(CROSS(MM4,MM1),21)>0 AND
COUNT(CROSS(MM3,MM2),21)>0 AND COUNT(CROSS(MM4,MM2),21)>0;
ZTJ:=COUNT(TSJ,13)>0 AND COUNT(DXJ,13)>0;
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);
==============================================================
天上井地下井：
5日、10日价格均线跌破20、30日均线形成一个井字这是天上井，在此前后同样周期的量均线也形成这样的井字，
是地下井
这是一个空头选股公式。
操作：
如果出现在高位，则表示头部形成，要及时逢高派发。
==============================================================
条件选股公式：D!TUO (价托) 缺省周期：日线
==============================================================
参数描述： N1(2,200,20)N2(2,200,40)N3(2,200,60)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3) AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);
==============================================================
价托：
短期、中期、长期三条均线自下而上扭转向上所形成的封闭三角形。常用的有季托与月托：
由5、10、20日均线这个月均线系统组成的托为“月托”；
由20、40、60日均线这个季均线系统组成的托为“季托”；
操作：
1、在三个黄金交叉点附近分批逢低买入。
2、看清楚价托后在回档时逢低买入。
==============================================================
构成价托的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月托取5，10，20；
季托取20，40，60；
==============================================================
条件选股公式：D!TWOJTUO (双价托) 缺省周期：日线
==============================================================
参数描述： N1(1,300,20)N2(1,300,40)N3(1,300,60)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3){COUNT(CROSS(MA2,MA3),21)=1} AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);
A1:=TUO AND REF(BARSLAST(TUO),1)<89;
==============================================================
双价托：
1、水平的双价托图形说明股价在此处受到两个价托的支撑，相对地比一个价托更有支撑力。
2、一个低位托使股价抬高到一定的震荡洗筹位，此时股价很难再度回到低位的价位托。再次形成价托，
说明股价受到双重支撑，还会有上升空间。
操作：
1、对于水平的双托，可以在第二个托形成后逢低买入。
2、对于一低一高的双价托，可以在第二个托形成后逢低吸纳，或在股价冲过前一头部的瞬间跟进。
==============================================================
构成双价托的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月托取5，10，20；季托取20，40，60；
==============================================================
条件选股公式：D!VOLTUO (量托) 缺省周期：日线
==============================================================
参数描述： N1(1,100,5)N2(1,100,10)N3(1,100,20)
==============================================================
MA1:=MA(V,N1);
MA2:=MA(V,N2);
MA3:=MA(V,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3){COUNT(CROSS(MA2,MA3),21)=1} AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);
==============================================================
量托：
短期、中期、长期三条成交量均线自上而上扭转向上所形成的封闭三角形。常用的有季托与月托：
由5、10、20日成交量均线组成的托为“月量托”；
由20、40、60日成交量均线组成的托为“季量托”；
操作：
1、月量托出现后，应该尽快逢低买入。
2、月量托出现后，如果K线图上出现月价托，更应积极入市。
==============================================================
构成量托的均线日期:
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月托取5，10，20；季托取20，40，60；
==============================================================
条件选股公式：D!VOLYA (量压) 缺省周期：日线
==============================================================
参数描述： N1(1,100,5)N2(1,100,10)N3(1,100,20)
==============================================================
MA1:=MA(V,N1);
MA2:=MA(V,N2);
MA3:=MA(V,N3);
YA:=COUNT(CROSS(MA2,MA1),21)=1 AND CROSS(MA3,MA2) AND
COUNT(CROSS(MA3,MA1),21)=1 AND
BARSLAST(CROSS(MA2,MA1))>BARSLAST(CROSS(MA3,MA1)) AND
BARSLAST(CROSS(MA3,MA1))>BARSLAST(CROSS(MA3,MA2)) AND
MA1<REF(MA1,1);
==============================================================
量压：
短期、中期、长期三条成交量均线自下而上扭转向下所形成的封闭三角形。常用的有季压与月压：
由5、10、20日成交量均线组成的压为“月量压”；
由20、40、60日成交量均线组成的压为“季量压”；
操作：
1、月量压出现后，应该尽快逢高派发。
2、月量压出现后，如果K线图上出现月价压，更应彻底派发。
注意：本公式为空头选股公式。
==============================================================
构成量压的均线日期:
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月压取5，10，20；季压取20，40，60；
==============================================================
条件选股公式：D!YYSCSJT (一阳上穿三角托) 缺省周期：日线
==============================================================
参数描述： N1(1,300,20)N2(1,300,40)N3(1,300,60)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3){COUNT(CROSS(MA2,MA3),21)=1} AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);
A1:=C>MAX(MA1,MAX(MA2,MA3)) AND O<MIN(MA1,MIN(MA2,MA3));
A2:=COUNT(A1,21)=1;
TUO AND A2;
==============================================================
一阳上穿三角托：
一根长阳线自下而上穿过价托。
操作：
1、在出现一阳上穿三角托后应及时逢低买入。
2、一般情况下第二天会跳空高开，应在前一天收盘前或第二天回档时买入。
==============================================================
构成一阳上穿三角托的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月托取5，10，20；季托取20，40，60；
==============================================================
条件选股公式：D!YYXCSJY (一阴下穿三角压) 缺省周期：日线
==============================================================
参数描述： N1(1,300,20)N2(1,300,40)N3(1,300,60)
==============================================================
MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
YA:=COUNT(CROSS(MA2,MA1),21)=1 AND CROSS(MA3,MA2) AND
COUNT(CROSS(MA3,MA1),21)=1 AND
BARSLAST(CROSS(MA2,MA1))>BARSLAST(CROSS(MA3,MA1)) AND
BARSLAST(CROSS(MA3,MA1))>BARSLAST(CROSS(MA3,MA2)) AND
MA1<REF(MA1,1);
A1:=O>MAX(MA1,MAX(MA2,MA3)) AND C<MIN(MA1,MIN(MA2,MA3));
A2:=COUNT(A1,21)=1;
YA AND A2;
==============================================================
一阴下穿三角压：
一根长阴线下穿价压。
操作：
逢高卖出。
注意：本公式为空头公式。
==============================================================
构成一阴下穿三角压的均线日期
短期Param#1日均线;
中期Param#2日均线;
长期Param#3日均线;
一般情况下：月取5，10，20；季取20，40，60；
==============================================================
技术指标公式：D!CDJXXT (超短均线系统) 缺省周期：60分钟
==============================================================
５单位:MA(C,5);
１０单位:MA(C,10);
２０单位:MA(C,20);
==============================================================
！！注意：本指标除15、30、60分钟外其余均为禁用周期！！
超短均线系统：
在60分钟K线、30分钟K线甚至15分钟K线图上，用5单位、10单位、20单位均线组成超短线均线系统。
这为我们进行微观分析提供了条件。
主要用来监视被怀疑的头部和底部的微观形态。
==============================================================
技术指标公式：D!DCJHJX (短、长结合的均线系统) 缺省周期：日线
==============================================================
短长结合均线5日:MA(C,5);
１０日均线:MA(C,10);
６０日均线:MA(C,60);
==============================================================
短长结合的均线系统：
5日、10日均线组成短线系统。
60日均线确认长线趋势。
“青龙探水”与本指标有关。见五彩K线之D!QLTS
==============================================================
技术指标公式：D!JJX (季均线系统) 缺省周期：日线
==============================================================
季均线系统20日:MA(C,20);
４０日均线:MA(C,40);
６０日均线:MA(C,60);
==============================================================
季均线系统：
20日、40日、60日均线组成。
==============================================================
技术指标公式：D!YJJXXT (月、季结合均线系统) 缺省周期：日线
==============================================================
月季结合均线5日:MA(C,5);
１０日:MA(C,10);
２０日:MA(C,20);
４０日:MA(C,40);
６０日:MA(C,60);
==============================================================
月、季结合的均线系统：
5日、10日、20日、40日、60日这五条均线组成。
月均线系统中的月价托为短、中期底部，在股价下跌过程中，有时会出现几个月价托，只有与季托重叠的那个托才是具有中、长期底部意义的托。
压与此相同。
==============================================================
技术指标公式：D!YJX (月均线系统) 缺省周期：日线
==============================================================
月均线系统5日:MA(C,5);
１０日均线:MA(C,10);
２０日均线:MA(C,20);
==============================================================
月均线系统：
5日、10日、20日均线组成。
月均线系统中的月价托为短、中期底部。
压与此相同。
