资金流向，我学写公式（源码 副图 贴图）介绍
资金流向，我学写公式（源码 副图 贴图）
我是个新人，想学习更多的知识，看到感觉有用的想发上来和大家分享，这是转自潘启明老师的博文，希望对大家能有所帮助。
{资金流向}
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出货:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
PJJ:=DMA((H+L+C*2)/4,0.9);
JJ:=REF(EMA(PJJ,3),1);
QJJ:=VOL/((H-L)*2-ABS(C-O));
XVL:=IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2));
ZLL:=VOL/CAPITAL;
HSL1:=IF(ZLL>10,10,ZLL);
HSL:=XVL/1000/1.15;
攻击流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22;
GJJ:=EMA(攻击流量,8);
LLJX:=EMA(攻击流量,3);
流量:LLJX,COLORC875B7,COLORRED,NODRAW;
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
流量基线:GJJ,COLOR00BBBB,COLORGREEN;
STICKLINE(HSL*0.4>=0,HSL*0.4*1.5,0,0,1),COLORYELLOW;
STICKLINE(HSL*0.4<0,HSL*0.4*1.5,0,0,1),COLORGREEN;
ZJLL:=REF(LLJX,1);
QZJJ:=(((LLJX-ZJLL)/ZJLL)*100);
流量幅%:IF(((LLJX>0) AND (ZJLL<0)),ABS(QZJJ),IF((((LLJX<0) AND (ZJLL<0)) AND (LLJX<ZJLL)),(0-QZJJ),QZJJ))COLORMAGENTA,NODRAW;
力度:HSL/1000,COLOR9B37FF,COLORRED,NODRAW;
周流量:SUM(LLJX,5),COLORFFBFDF,COLORMAGENTA,NODRAW;
BB:=REF(周流量,1);
ZQZJJ:=(周流量-BB)/BB*100;
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ))COLORMAGENTA,NODRAW;
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3);
主力进场:STICKLINE(VARQ5>REF(VARQ5,1) AND 出货<=0,0,VARQ5,1,0),COLORWHITE;
我看到《资金流向》好用，但不知道它的数值的涵义，我就把它下载下来：
然后我就一点点研究它。
我知道DYNAINFO(7)的意思是现价。但不知道DYNAINFO(7)的涵义是什么。所以我就写一行代码：
现价:DYNAINFO(7);
电脑执行后，发现是贯通左右的当前股价的一条线。
接着，我同年我刚写的现价那一行，去掉原程序第一行冒号后的等号，输入到电脑：
ZC_1:IF(LDYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
H为最高价，L为最低价。电脑执行后，发现比现价高的股价就画到现价之上指定位置，否则归零。再恢复第一行的等号，不再显示它，用同样的方法，去掉等号，处理下一行。
ZC_2:DMA(ZC_1,V/CAPITAL)*100;
V为成交量(手)；CAPITAL为当前流通股本(手)；DMA为动态移动平均。电脑执行后，发现它是把ZC_1线改成曲线，数值放大100倍。用同样的方法（即将刚显示过的那一行，在冒号后加上等号，不显示它），再写下一行：
出货:IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
这行的涵义是：如果ZC_2>0ANDZC_2>昨日ZC_2,返回ZC_2/20,否则返回0。电脑执行后，发现它是：如果ZC_2上涨，则取ZC_2的20分一之值，否则归零。
然后就这样，一行行往电脑里写，一行行看，它是什么意思。输入进去的原指标的语句不能删，只能在冒号后加上等号，不显示它！能够删除的，是自己为了了解字符串涵义而写上的语句。这样，我就明白了：
PJJ:DMA((H+L+C*2)/4,0.9); 平均价的九成，画均线。
JJ:REF(EMA(PJJ,3),1); 三天前的九成平均均线。
把VOL和QJJ同时展示：
量:VOL,COLORRED;
QJJ:VOL/((H-L)*2-ABS(C-O));
ABS是取绝对值；C是收盘价；O 是开盘价。QJJ取VOL之均价平缓值，价高时减少了VOL，而价低时增加了VOL。
XVL:IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2)); XVL的绝对值通常是VOL的1/2左右。股价收阴，则XVL为负。
ZLL:VOL/CAPITAL; 以小数点表示的换手率
HSL1:=IF(ZLL>10,10,ZLL); 换手率不大于10
HSL:=XVL/1000/1.15; XVL/1000/1.15,即是 XVL/1150， 取XVL的1150分之一。
攻击流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22; 0.55的当天缩小成交量+0.33的缩小昨日+0.22前天缩小成交量。继续往下写三行：
GJJ:=EMA(攻击流量,8);
LLJX:=EMA(攻击流量,3);
流量:LLJX,COLORC875B7,COLORRED,NODRAW;
流量就是LLJX，以下的程序代码中，“LLJX”全部改成“流量”。COLORC875B7 和 COLORRED 两种颜色重复，只取一种。以下的代码中，还有多次这种情况，一律只要用英文直白说出颜色的那个代码。NODRAW表示不显示图象，但保留显示数字。上两行合并成：
流量:=EMA(攻击流量,3),COLORRED,NODRAW;
STICKLINE是画色柱，
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
色柱的意义很明白：
当满足条件流量>0时,在流量和0位置之间画柱状线,宽度为2.3,0不为0则画空心柱.,画红色
当满足条件流量<0时,在流量和0位置之间画柱状线,宽度为2.3,0不为0则画空心柱.,COLORFF4242
为了节省篇幅，不一一解释了，如果需要，只在行后做一点说明。代码用蓝色，说明用黑色。
流量基线:GJJ,COLOR00BBBB,COLORGREEN; COLOR00BBBB 是多余的，可以删掉。
STICKLINE(HSL*0.4>=0,HSL*0.4*1.5,0,0,1),COLORYELLOW; 细柱线，黄色。
STICKLINE(HSL*0.4<0,HSL*0.4*1.5,0,0,1),COLORGREEN; 细柱线，绿色。
ZJLL:=REF(,1); 前一日的流量。
QZJJ:=(((流量-ZJLL)/ZJLL)*100); 数学算式的涵义很清楚，不解释。
流量幅%:IF(((流量>0) AND (ZJLL<0)),ABS(QZJJ),IF((((流量<0) AND (ZJLL<0)) AND (流量<ZJLL)),(0-QZJJ),QZJJ))COLORMAGENTA,NODRAW; 流量幅%的数值是：如果满足((流量>0)和(ZJLL<0)二个条件)，返回QZJJ的绝对值，否则[如果满足(((流量<0)和(ZJLL<0))和(流量<ZJLL)三个条件)，返回(0-QZJJ)]，否则返回QZJJ，画洋红色，只显示数字，不画图。原代码COLORMAGENTA前，应加“,”号。
力度:HSL/1000,COLOR9B37FF,COLORRED,NODRAW; 缩小1000倍。COLOR9B37FF, 是多余的，可以删掉。
周流量:SUM(流量,5),COLORFFBFDF,COLORMAGENTA,NODRAW; 五日流量。COLORFFBFDF, 是多余的，可以删掉。
BB:=REF(周流量,1); 前一日流量。
ZQZJJ:=(周流量-BB)/BB*100; 数学算式的涵义很清楚，不解释。
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ))COLORMAGENTA,NODRAW; 流量幅%的数值是：周幅%:如果周流量>0和BB<0,返回ZQZJJ的绝对值,否则返回如果周流量<0和BB<0AND周流量<BB,返回-ZQZJJ,否则返回ZQZJJ，画洋红色，只显示数字，不画图。原代码COLORMAGENTA前，应加“,”号。
以下是底警示，提示建仓位置
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1); 前一日平均价。
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),10,1); 和K线是反向的。10日可能是数值很小的小数，由于已将实际成交量缩小了1000倍，所以改成15日比较谐调。
VARQ3:=EMA(VARQ2,10); 和K线是反向的。
VARQ4:=LLV(LOW,33); 33日内的最低价。
{VARQ5:=EMA(IF(LOW<=VARQ4,VARQ3,0),3);} 这是原代码。由于有时数值会非常大，我把它改成下行。为仍能保留在公式中，我加了大引号“{}”
VARQ5:=EMA(IF(LOW<=VARQ4 AND VARQ3<=250,VARQ3/2,IF(VARQ3>250,VARQ3/10,0)),3);
主力进场:STICKLINE(VARQ5>REF(VARQ5,1) AND 出货<=0,0,VARQ5,1,0),COLORWHITE; 画白色柱线。
--------------------------------
如果我们再加上“持股成本”和“流通亿股”，再调整一下颜色，可以把《资金流向》写成：
{资金流向}
成本:DMA(AMOUNT/V/100,V/CAPITAL),NODRAW,COLOREEFFCC;
ZC_1:=IF(L<DYNAINFO(7),0,IF(H>DYNAINFO(7),DYNAINFO(7)-(DYNAINFO(7)-H+0.02)/(H-L+0.02),0));
ZC_2:=DMA(ZC_1,V/CAPITAL)*100;
出货:=IF(ZC_2>0 AND ZC_2>REF(ZC_2,1),ZC_2/20,0);
PJJ:=DMA((H+L+C*2)/4,0.9);
JJ:=REF(EMA(PJJ,3),1);
量:=VOL,COLORRED;
QJJ:=VOL/((H-L)*2-ABS(C-O));
XVL:=IF(C>O,QJJ*(H-L),IF(C<O,QJJ*(H-O+(C-L)),VOL/2))+IF(C>O,0-QJJ*(H-C+(O-L)),IF(C<O,0-QJJ*(H-L),0-VOL/2));
ZLL:=VOL/CAPITAL;
HSL1:=IF(ZLL>10,10,ZLL);
HSL:=XVL/1150;
攻击流量:=HSL*0.55+REF(HSL,1)*0.33+REF(HSL,2)*0.22;
GJJ:=EMA(攻击流量,8),COLORRED;
流量:EMA(攻击流量,3),COLORRED,NODRAW;
STICKLINE(流量>0,流量,0,2.3,0),COLORRED;
STICKLINE(流量<0,流量,0,2.3,0),COLORFF4242;
流量基线:GJJ,COLORGREEN;
STICKLINE(HSL>=0,HSL*0.6,0,0,1),COLORYELLOW;
STICKLINE(HSL<0,HSL*0.6,0,0,1),COLORGREEN;
ZJLL:=REF(流量,1);
QZJJ:=(((流量-ZJLL)/ZJLL)*100);
流量幅%:IF(((流量>0) AND (ZJLL<0)),ABS(QZJJ),IF((((流量<0) AND (ZJLL<0)) AND (流量<ZJLL)),(0-QZJJ),QZJJ)),COLORMAGENTA,NODRAW;
力度:=HSL/1000,COLORRED,NODRAW;
周流量:SUM(流量,5),COLORYELLOW,NODRAW;
BB:=REF(周流量,1);
ZQZJJ:=(周流量-BB)/BB*100;
周幅%:IF(周流量>0 AND BB<0,ABS(ZQZJJ),IF(周流量<0 AND BB<0 AND 周流量<BB,-ZQZJJ,ZQZJJ)),COLORWHITE,NODRAW;
VARQ1:=REF((LOW+OPEN+CLOSE+HIGH)/4,1);
VARQ2:=SMA(ABS(LOW-VARQ1),13,1)/SMA(MAX(LOW-VARQ1,0),15,1);
VARQ3:=EMA(VARQ2,10);
VARQ4:=LLV(LOW,33);
VARQ5:=EMA(IF(LOW<=VARQ4 AND VARQ3<=250,VARQ3/2,IF(VARQ3>250,VARQ3/10,0)),3);
主力进场:STICKLINE(VARQ5>REF(VARQ5,1) AND 出货<=0,0,VARQ5,1,0),COLORWHITE;
流通亿股:FINANCE(7)/100000000,NODRAW,COLOREEFFCC;
gd15414
