九全MACD (源码 原创 副图 贴图)介绍
九全MACD (源码 原创 副图 贴图)
前段时间，看到论坛上面的RACD、成交量MACD，深受启发。昨天，突发奇想，于是制作了这个《九全MACD》，调节指标参数，可以调用CCIMACD、RSIMACD、RSVMACD、BBIMACD、BIASMACD、能量潮MACD、成交量MACD、成交额MACD、标准MACD，默认参数为标准MACD。这是我的第一个自编指标，博方家一笑耳！
源代码如下：
{九全MACD}
INPUT:N(9,1,9);
{基本设定}
{CCI-14}
TYP:= (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
{RSI-12}
LC:= REF(CLOSE,1);
RSI:=SMA(MAX(CLOSE-LC,0),12,1)/SMA(ABS(CLOSE-LC),12,1)*100;
{RSV-9}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
{BBI}
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
{BIAS-12}
BIAS:=(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100;
{OBV}
OBV:=SUM(IF(CLOSE>REF(CLOSE,1),VOL,IF(CLOSE<REF(CLOSE,1),-VOL,0)),0);
{参数设定}
VARC:=IF(N=1,CCI,IF(N=2,RSI,IF(N=3,RSV,IF(N=4,BBI,IF(N=5,BIAS,IF(N=6,OBV,IF(N=7,VOL,IF(N=8,AMOUNT,C))))))));
{九全MACD}
DIFF:EMA(VARC,12)-EMA(VARC,26);
DEA: EMA(DIFF,9);
MACD: 2*(DIFF-DEA),COLORSTICK;
{提示}
IF N=1 THEN BEGIN
DRAWTEXTREL(15,40,'CCI-MACD'),color00FF00;
END;
IF N=2 THEN BEGIN
DRAWTEXTREL(15,40,'RSI-MACD'),color00FF00;
END;
IF N=3 THEN BEGIN
DRAWTEXTREL(15,40,'RSV-MACD'),color00FF00;
END;
IF N=4 THEN BEGIN
DRAWTEXTREL(15,40,'BBI-MACD'),color00FF00;
END;
IF N=5 THEN BEGIN
DRAWTEXTREL(15,40,'BIAS-MACD'),color00FF00;
END;
IF N=6 THEN BEGIN
DRAWTEXTREL(15,40,'能量潮-MACD'),color00FF00;
END;
IF N=7 THEN BEGIN
DRAWTEXTREL(15,40,'成交量-MACD'),color00FF00;
END;
IF N=8 THEN BEGIN
DRAWTEXTREL(15,40,'成交额-MACD'),color00FF00;
END;
IF N=9 THEN BEGIN
DRAWTEXTREL(15,40,'标准-MACD'),color00FF00;
END;
gd15609
