以下是带龙虎榜提示的自用主图 源码
带龙虎榜提示的自用主图 源码
这个指标也是我用系统指标MA根据看盘需要添加的一些K线关键位形态提示！1、决策提示线 2、量能平台 3、黄金柱 4、大盘指数自动叠加 5、龙虎榜异动自动提示（黄圆点）等等。。。！
另主图提示未来数据：“FINANC”，是通达信软件自带的财务函数！非一般的漂移函数！！！
源码
{N1 1 1000 5}
周期:=220;
自动C:=INDEXC;
自动O:=INDEXO;
自动H:=INDEXH;
自动L:=INDEXL;
指定O:="SH999999$O";
指定H:="SH999999$H";
指定L:="SH999999$L";
指定C:="SH999999$C";
大盘低:=CONST(LLV(指定L,周期));
大盘高:=CONST(HHV(指定H,周期));
大盘差:=大盘高-大盘低;
当前低:=CONST(LLV(L,周期));
当前高:=CONST(HHV(H,周期));
当前差:=当前高-当前低;
比1:=当前差/大盘差;
变C:=当前低+(指定C-大盘低)*比1;
变H:=当前低+(指定H-大盘低)*比1;
变L:=当前低+(指定L-大盘低)*比1;
变O:=当前低+(指定O-大盘低)*比1;
STICKLINE(CURRBARSCOUNT<周期,变H,变L,0,0),COLOR663300;
STICKLINE(CURRBARSCOUNT<周期,变O,变C,3,0),COLOR663300;
STICKLINE(CURRBARSCOUNT<周期 AND 变C>=变O,变O,变C,3,1),COLOR663300;
DRAWKLINE(H,O,L,C);
UR:=N1;
LR:=N1;
TC1:=IF(H=HHV(H,8*UR),H,DRAWNULL);
TC2:=CONST(BARSLAST(TC1=H))+1;
UP:=CONST(IF(TC2=1,H,REF(H,TC2-1)));
BC1:=IF(L=LLV(L,8*LR),L,DRAWNULL);
BC2:=CONST(BARSLAST(BC1=L))+1;
LL:=CONST(IF(BC2=1,L,REF(L,BC2-1)));
LP:=CURRBARSCOUNT<=BC2 AND L=LL;
HP:=CURRBARSCOUNT<=TC2 AND H=UP;
NOD:=(IF(TC2>BC2,TC2,BC2)-IF(TC2>BC2,BC2,TC2));
LR1:=FORCAST(C,NOD+1);
NP:=IF(CURRBARSCOUNT<=MAX(BC2,TC2),CONST(IF(MIN(TC2,BC2)=1,LR1,REF(LR1,MIN(TC2,BC2)-1))),DRAWNULL),POINTDOT,COLOR93BDA8;{近点}
LR2:=SLOPE(C,NOD+1);
LR3:=CONST(IF(MIN(TC2,BC2)=1,LR2,REF(LR2,MIN(TC2,BC2)-1)));
FP:=NP-LR3*(NOD),POINTDOT,COLOR93BDA8;
AD:=ABS(NP-FP);
DBL:=BARSLAST(BC1!=DRAWNULL)+1;
DBH:=BARSLAST(TC1!=DRAWNULL)+1;
BSP:=IF(BC2>TC2,DBL,DBH)-1;
LRL:=IF(NP>FP,FP+AD/NOD*BSP,FP-AD/NOD*BSP);
AT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND H>LRL,H,LRL);
AT2:=HHV(AT1-LRL,MAX(BC2,TC2));
AT3:=CONST(BARSLAST(AT1-LRL=AT2));
AT4:=CONST(IF(AT3=0,H,REF(H,AT3)));
AT5:=CONST(IF(AT3=0,AT1-LRL,REF(AT1-LRL,AT3)));
ATL:=LRL+AT5;
UT1:=IF(BETWEEN(CURRBARSCOUNT,BC2,TC2) AND L<LRL,L,LRL);
UT2:=HHV(LRL-UT1,MAX(BC2,TC2));
UT3:=CONST(BARSLAST(LRL-UT1=UT2));
UT4:=CONST(IF(UT3=0,H,REF(H,UT3)));
UT5:=CONST(IF(UT3=0,LRL-UT1,REF(LRL-UT1,UT3)));
UTL:=LRL-UT5;
RH:=IF(CURRBARSCOUNT>=MIN(BC2,TC2)-10,ATL,CONST(REF(ATL,MIN(BC2,TC2)-11)));
RL:=IF(CURRBARSCOUNT>=MIN(BC2,TC2)-10,UTL,CONST(REF(UTL,MIN(BC2,TC2)-11)));
上轨:IF(NP>FP,IF(ATL<=RH,ATL,DRAWNULL),IF(ATL>=RL,ATL,DRAWNULL)),COLORFF0066,DOTLINE;
中轨:IF(NP>FP,IF(LRL<=RH,LRL,DRAWNULL),IF(LRL>=RL,LRL,DRAWNULL)),COLORFF0066,DOTLINE;
下轨:IF(NP>FP,IF(UTL<=RH,UTL,DRAWNULL),IF(UTL>=RL,UTL,DRAWNULL)),COLORFF0066,DOTLINE;
降△边:DRAWLINE(HIGH>=HHV(HIGH,10),HIGH,LOW<=LLV(LOW,3),HHV(HIGH,3),1),COLORCYAN,DOTLINE;
涨△边:DRAWLINE(LOW<=LLV(LOW,10),LOW,HIGH>=HHV(HIGH,3),LLV(LOW,3),1),COLORLIRED,DOTLINE;
个涨:=(C-REF(C,1))*100/REF(C,1),NODRAW;
统计:=COUNT(个涨>6,3),NODRAW;
沪市:=("999998$C"-REF("999998$C",1))*100/REF("999998$C",1);
深市:=("399107$C"-REF("399107$C",1))*100/REF("399107$C",1),NODRAW;
中板:=("399101$C"-REF("399101$C",1))*100/REF("399101$C",1),NODRAW;
沪离:=(个涨+REF(个涨,1)+REF(个涨,2))-(沪市+REF(沪市,1)+REF(沪市,2));
深离:=(个涨+REF(个涨,1)+REF(个涨,2))-(深市+REF(深市,1)+REF(深市,2));
中离:=(个涨+REF(个涨,1)+REF(个涨,2))-(中板+REF(中板,1)+REF(中板,2));
偏离廿:=IF(CODELIKE('6'),沪离,IF(CODELIKE('000'),深离,中离)),NODRAW;
沪涨:=个涨-沪市;
深涨:=个涨-深市;
中涨:=个涨-中板;
偏离七:=IF(CODELIKE('6'),沪涨,IF(CODELIKE('000'),深涨,中涨)),NODRAW;
龙:=偏离廿>20 AND 统计>2,NODRAW;
虎:=(偏离七>7 AND 个涨>5) OR (偏离七<-7 AND 个涨<-5),NODRAW;
换:=100*VOL/(FINANCE(7)/100),NODRAW;
振:=(H-L)*100/REF(C,1),NODRAW;
虎盘:=龙 OR 虎 OR 换>20 OR 振>15,NODRAW;
DRAWICON(虎盘 AND PERIOD=5,HIGH+0.09,41);
VOL5:=MA(VOL,5),COLORWHITE;
VOL10:=MA(VOL,10),COLORYELLOW;
VOL40:=MA(VOL,40),COLORFF00FF;
三日不破:=MIN(MIN(L,REF(L,1)),REF(L,2))>=REF(L,3);
三日量缩:=(MAX(MAX(V,REF(V,1)),REF(V,2))<REF(V,3));
三日价涨A:=C>=REF(C,1);
三日价涨B:=C<REF(C,1);
三日价涨C:=MIN(MIN(C,REF(C,1)),REF(C,2))>=REF(L,3);
TIM:=IF(DATE<1140214,1,0);
缩倍柱:=(VOL*1.95<=REF(VOL,1))*TIM;
百日低量:=(VOL=LLV(VOL,100))*TIM;
倍量柱:=C>REF(C,1)*1.04 AND (VOL>=1.9*REF(VOL,1))*TIM;
四日前倍量柱:=(REF(VOL,3)>1.9*REF(VOL,4))*TIM;
四日前高量柱:=(REF(VOL,3)>=REF(VOL,4) AND REF(VOL,3)<1.9*REF(VOL,4) AND 三日量缩)*TIM;
前三引用不成立:=COUNT(REF(四日前倍量柱,1) AND (REF(三日不破,1) OR REF(三日价涨C,1)),3)=0 AND COUNT(REF(四日前高量柱,1) AND (REF(三日不破,1) OR REF(三日价涨C,1)),3)=0;
倍量黄金柱:=四日前倍量柱 AND 三日量缩 AND 三日不破 AND 三日价涨A AND 前三引用不成立;
高量黄金柱:=四日前高量柱 AND 三日量缩 AND 三日不破 AND 三日价涨A AND 前三引用不成立;
黄金柱:=倍量黄金柱 OR 高量黄金柱;
次倍量黄金柱:=NOT(黄金柱) AND 四日前倍量柱 AND 三日量缩 AND 三日不破 AND 三日价涨B AND 前三引用不成立;
次高量黄金柱:=NOT(黄金柱) AND 四日前高量柱 AND 三日量缩 AND 三日不破 AND 三日价涨B AND 前三引用不成立;
次黄金柱:=次倍量黄金柱 OR 次高量黄金柱;
准倍量黄金柱:=NOT(黄金柱 OR 次黄金柱) AND 四日前倍量柱 AND ((三日量缩 AND 三日价涨C) OR (COUNT(倍量柱,3)>=1 AND 三日不破)) AND 前三引用不成立;
准高量黄金柱:=NOT(黄金柱 OR 次黄金柱) AND 四日前高量柱 AND (三日量缩 AND 三日价涨C) AND 前三引用不成立;
准黄金柱:=准倍量黄金柱 OR 准高量黄金柱;
倍量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱) AND 四日前倍量柱 AND 三日不破 AND 三日价涨A AND 前三引用不成立;
高量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱) AND 四日前高量柱 AND 三日不破 AND 三日价涨A AND 前三引用不成立;
将军柱:=倍量将军柱 OR 高量将军柱;
次倍量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱 OR 将军柱) AND 四日前倍量柱 AND 三日不破 AND 三日价涨B AND 前三引用不成立;
次高量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱 OR 将军柱) AND 四日前高量柱 AND 三日不破 AND 三日价涨B AND 前三引用不成立;
次将军柱:=次倍量将军柱 OR 次高量将军柱;
准倍量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱 OR 将军柱 OR 次将军柱) AND 四日前倍量柱 AND 三日价涨C AND 前三引用不成立;
准高量将军柱:=NOT(黄金柱 OR 次黄金柱 OR 准黄金柱 OR 将军柱 OR 次将军柱) AND 四日前高量柱 AND 三日价涨C AND 前三引用不成立;
准将军柱:=准倍量将军柱 OR 准高量将军柱;
JJ:=(3*C+H+L+O)/6;
VARA1:=(8*JJ+7*REF(JJ,1)+6*REF(JJ,2)+5*REF(JJ,3)+4*REF(JJ,4)+3*REF(JJ,5)+2*REF(JJ,6)+REF(JJ,8))/36;
TTJ1:=VOL=HHV(VOL,10) AND VOL>2*REF(VOL,1) AND CLOSE>VARA1 AND C>REF(C,1);
LJL:=FILTER(TTJ1,5);
TTJ2:=IF(BARSLAST(LJL)=1 AND CLOSE>REF(HIGH,1),1,IF(BARSLAST(LJL)=2 AND CLOSE>REF(HIGH,2),1,IF(BARSLAST(LJL)=3 AND CLOSE>REF(HIGH,3),1,0)));
TP:=TTJ2=1;
STICKLINE(CLOSE,REF(LOW,BARSLAST(LJL)),REF(LOW,BARSLAST(LJL)),6,0),COLORYELLOW;{划线}
TTJ3:=IF(BARSLAST(LJL)=1 AND CLOSE>REF(LOW,1),1,IF(BARSLAST(LJL)=2 AND CLOSE>REF(LOW,2),1,IF(BARSLAST(LJL)=3 AND CLOSE>REF(LOW,3),1,0)));
STFZ:=TTJ3=1;
CL:=STFZ AND TP;
TJCL:=FILTER(CL,3);
STICKLINE(LJL,C,O,2,0),COLORYELLOW;
MA5:MA(CLOSE,5),COLORWHITE;
MA10:MA(CLOSE,10),COLORYELLOW;
MA20:MA(CLOSE,20),COLORLIMAGENTA;
MA60:MA(CLOSE,60),COLORGREEN;
MA120:MA(CLOSE,120),COLORBLUE;
MA250:MA(CLOSE,250);
DP:=IF(C=INDEXC,0,1);
GJ:=AMOUNT/V/100;
【明日阻力】:L+(GJ-L)+(C-L),COLORRED,NODRAW;
【明日支撑】:L+(C-GJ),NODRAW;
年:=YEAR,NODRAW;
月:=MONTH,NODRAW;
星期:=WEEKDAY,NODRAW;
日1:=DATETODAY(DATE);
上市日:=REF(DATE,TOTALBARSCOUNT-CURRBARSCOUNT);
自然日:=日1-DATETODAY(上市日)+1;
ZB:=(自然日-REF(自然日,1))!=星期-REF(星期,1)
OR TOTALBARSCOUNT-CURRBARSCOUNT=0;
本周第几天:=BARSLAST(ZB)+1;
本月第几天:=BARSLAST(年*100+月!=REF(年*100+月,1))+1;
M1:=REF(C,本周第几天);
M2:=REF(M1,本周第几天);
M3:=REF(M2,本周第几天);
M4:=REF(M3,本周第几天);
M5:=REF(M4,本周第几天);
M6:=REF(M5,本周第几天);
M7:=REF(M6,本周第几天);
M8:=REF(M7,本周第几天);
M9:=REF(M8,本周第几天);
十周价:=(C+M1+M2+M3+M4+M5+M6+M7+M8+M9)/10;
决策:REFDATE(十周价,DATE),COLORBROWN,LINETHICK1;
DRAWTEXT(ISLASTBAR,决策,' 决策线'),COLORBROWN;
DRAWTEXT_FIX(C>0,0.004,0.0001,0,STRCAT('三季报业绩：',EXTERNSTR(0,10))),COLORLIRED,LINETHICK2;
{DRAWTEXT_FIX(C>0,0.004,0.05,0,STRCAT('一季报业绩：',EXTERNSTR(0,8))),COLORBROWN,LINETHICK2;}
{DRAWTEXT_FIX(C>0,0.004,0.1,0,STRCAT('中报预报：',EXTERNSTR(0,6))),COLORLIGRAY,LINETHICK2;}
DRAWTEXT_FIX(C>0,0.004,0.05,0,STRCAT('年报预告：',EXTERNSTR(0,16))),COLORWHITE,LINETHICK2;
DRAWTEXT_FIX(C>0,0.004,0.1,0,STRCAT('股东变动：',EXTERNSTR(0,9))),COLORLIGRAY,LINETHICK2;
DRAWTEXT_FIX(C>0,0.004,0.15,0,STRCAT('机构持仓：',EXTERNSTR(0,1))),COLORLIGRAY,LINETHICK2;
{DRAWTEXT_FIX(ISLASTBAR,0,0,0,GNBLOCK),COLORYELLOW;}{概念板块左上角}
DRAWTEXT_FIX(ISLASTBAR,0,28,0,GNBLOCK),COLOR0099CC;{板块概念左下角}
DRAWTEXT_FIX(1,0.34,28,0,HYBLOCK)COLOR0099CC;{所属行业左下角}
DRAWTEXT_FIX(1,0.40,28,0,DYBLOCK)COLOR0099CC;{所属地区左下角}
DRAWTEXT_FIX(1,0.48,28,0,EXTERNSTR(0,2))COLOR0099CC;{主题投资左下角};
半分位:=(O+C)/2;
昨半分位:=REF(半分位,1);
STICKLINE(ISLASTBAR,昨半分位,昨半分位,10,0),COLORWHITE;
DRAWNUMBER(ISLASTBAR,昨半分位,昨半分位),COLORBROWN;
DRAWTEXT(ISLASTBAR,昨半分位,' 昨半分位'),COLORGRAY;
